% The Computer Modern Roman family of fonts (by D. E. Knuth, 1979--1985)
% Caps only
font_coding_scheme:="CAPS";

mode_setup; font_setup;
input romanu;	% upper case (majuscules)
font_slant slant;
if monospace: font_normal_space 9u#; % no stretching or shrinking
 font_xheight x_height#;
 font_quad 18u#;
 font_extra_space 9u#;
else: font_normal_space 6u#+2letter_fit#;
 font_normal_stretch 3u#; font_normal_shrink 2u#;
 font_xheight x_height#;
 font_quad 18u#+4letter_fit#;
 font_extra_space 2u#;
 numeric k,kk,kkk; k=-.5u#; kk=-1.5u#; kkk=-2u#; % three degrees of kerning
 ligtable "P": "A" kern kk;
 ligtable "F": "V": "W": "A" kern kkk,
  "K": "X": "O" kern k, "C" kern k, "G" kern k, "Q" kern k;
 ligtable "T":
  "Y": "A" kern kk;
 ligtable "O": "D": "A" kern k, "W" kern k, "Y" kern k, "V" kern k, "X" kern k;
 ligtable "A": if serifs: "R": fi
  "L": "T" kern kk, "O" kern k, "U" kern k, "C" kern k,
   "W" kern kkk, "Y" kern kk, "G" kern k, "V" kern kkk, "Q" kern k;
 ligtable "I": "I" kern -k; % Richard III
fi;
if known Xerox_world: font_family font_identifier;
 coding_scheme font_coding_scheme;
 font_face_byte 254-2 round designsize; fi % Dover code for CM; 154==AM
tracingstats:=10; % temporary
end.